HMGforum.com

Code: Select all

*-----------------------------------------------------------------------------*
Function InputBox ( cInputPrompt , cDialogCaption , cDefaultValue , nTimeout , cTimeoutValue , lMultiLine )
*-----------------------------------------------------------------------------*

	Local RetVal , mo

	DEFAULT cInputPrompt	TO ""
	DEFAULT cDialogCaption	TO ""
	DEFAULT cDefaultValue	TO ""

	RetVal := ''

	If ValType (lMultiLine) != 'U'
		If lMultiLine == .T.
			mo := 150
		Else
			mo := 0
		EndIf
	Else
		mo := 0
	EndIf

	DEFINE WINDOW _InputBox 		;
		AT 0,0 				;
		WIDTH 350 			;
		HEIGHT 115 + mo	+ GetTitleHeight() ;
		TITLE cDialogCaption  		;
		MODAL 				;
		ON SIZE _InputBoxAdjust()	;
		FONT 'Arial'			;
		SIZE 10

		ON KEY CONTROL+W ACTION ( _HMG_SYSDATA [ 257 ] := .F. , RetVal := _InputBox._TextBox.Value , _InputBox.Release ) 
		ON KEY ESCAPE ACTION ( _HMG_SYSDATA [ 257 ] := .T. , _InputBox.Release )

		@ 07,10 LABEL _Label		;
			VALUE cInputPrompt	;
			AUTOSIZE
// JK
                If ValType (lMultiLine) != 'U' .and. lMultiLine == .T.
                @ 30,10 EDITBOX _TextBox	;
			VALUE cDefaultValue	;
			HEIGHT 26 + mo		;
			WIDTH 320		
                else
		@ 30,10 TEXTBOX _TextBox	;
			VALUE cDefaultValue	;
			HEIGHT 26 + mo		;
			WIDTH 320		;
			ON ENTER ( _HMG_SYSDATA [ 257 ] := .F. , RetVal := _InputBox._TextBox.Value , _InputBox.Release )

                endif
// 
		@ 67+mo,120 BUTTON _Ok		;
			CAPTION if( Set ( _SET_LANGUAGE ) == 'ES', 'Aceptar' ,'Ok' )		;
			ACTION ( _HMG_SYSDATA [ 257 ] := .F. , RetVal := _InputBox._TextBox.Value , _InputBox.Release ) 

		@ 67+mo,230 BUTTON _Cancel		;
			CAPTION if( Set ( _SET_LANGUAGE ) == 'ES', 'Cancelar', 'Cancel'	);
			ACTION   ( _HMG_SYSDATA [ 257 ] := .T. , _InputBox.Release )

			If ValType (nTimeout) != 'U'

				If ValType (cTimeoutValue) != 'U'

					DEFINE TIMER _InputBox ;
					INTERVAL nTimeout ;
					ACTION  ( RetVal := cTimeoutValue , _InputBox.Release ) 

				Else

					DEFINE TIMER _InputBox ;
					INTERVAL nTimeout ;
					ACTION _InputBox.Release

				EndIf
	
			EndIf

	END WINDOW

	If _InputBox._Label.Width > 280
		_InputBox.Width := _InputBox._Label.Width + 35
	EndIf

	_InputBox._TextBox.SetFocus 

	CENTER WINDOW _InputBox

	ACTIVATE WINDOW _InputBox	

Return ( RetVal )
*-----------------------------------------------------------------------------*
Static Procedure _InputBoxAdjust()
*-----------------------------------------------------------------------------*
Local nWidth  := _InputBox.Width
Local nHeight := _InputBox.Height
Local nTitleH := GetTitleHeight()

	If nWidth < 350
		_InputBox.Width := 350
		Return
	EndIf

	If nHeight < 115 + nTitleH
		_InputBox.Height := 115 + nTitleH
		Return
	EndIf

	_InputBox._TextBox.Width  := nWidth  - 30
	_InputBox._TextBox.Height := nHeight - 89 - nTitleH

	_InputBox._Ok.Row         := nHeight - 48 - nTitleH
	_InputBox._Ok.Col         := nWidth  - 230

	_InputBox._Cancel.Row     := nHeight - 48 - nTitleH
	_InputBox._Cancel.Col     := nWidth  - 120

Return