don´t run App twice

[AUGE_OHR]

hi,

how to avoide to run 2nd Instance of App under harbour / HMG

[dragancesu]

see in help

SET MULTIPLE ON | OFF [ WARNING ]

[AUGE_OHR]

hi,

Code: Select all

SET MULTIPLE OFF

does work ... but i want "more"

when App is already working but e.g. in Tasklist i want to "SetForegroundWindow()"

---

use Xbase++ it does start :

ERRORSYS
DBESYS // RDD
APPSYS

before Main so i have this in AppSys

Code: Select all

PROCEDURE AppSys()
LOCAL cTitle  := "XCM " + VERSION()
LOCAL hWndDlg := @User32:FindWindowA( 0, cTitle )
   IF !( hWndDlg == 0 )
      @ User32:SetForegroundWindow( hWndDlg )
      @ User32:BringWindowToTop( hWndDlg )
      @ User32:ShowWindow( hWndDlg, 1 )
      @ User32:UpdateWindow( hWndDlg )
      // ** It is a second instance....  Bye-Bye
      QUIT
   ENDIF
RETURN

so how do it under harbour / HMG

[serge_girard]

Woudl be nice to have!
Serge

[gfilatov]

Woudl be nice to have!

Serge,

We have the following simple sample below:

Code: Select all

#include <minigui.ch>

Procedure MAIN
Local cTitle := 'One Instance Sample'
 
OnlyOneInstance( cTitle )
 
DEFINE WINDOW Main ;
   WIDTH 600       ;
   HEIGHT 400      ;
   TITLE cTitle    ;
   MAIN

END WINDOW

Main.Center
Main.Activate

Return


Function OnlyOneInstance( cAppTitle )
Local hWnd := FindWindowEx( ,,, cAppTitle )
 
if hWnd # 0
   iif( IsIconic( hWnd ), _Restore( hWnd ), SetForeGroundWindow( hWnd ) )
   ExitProcess( 0 )
endif

Return NIL

Hope that helps

[serge_girard]

Great!

[mol]

Where is defined function IsIconic?
Is it present in HMG, too?

[gfilatov]

Where is defined function IsIconic?
Is it present in HMG, too?

Marek,

Sure.
Please add the following translate statement in your HMG code:

Code: Select all

#xtranslate IsIconic ( <hWnd> ) => IsMinimized ( <hWnd> )

[serge_girard]

Hi Grigory, WHat about _Restore in HMG?
Serge

[gfilatov]

Hi Grigory, WHat about _Restore in HMG?

Hi Serge,

It is

Code: Select all

#xtranslate _Restore( <h> ) => Restore( <h> )